Öffentliche Aufgaben erstellen

[Stixx 10]

Hallo zusammen,

 

ich habe ein kleines bzw. für mich großes Problem. Wir haben einen Exchange unter 2000 am laufen. Ich will einen Ordner Aufgaben für EDV erstellen, bei dem die User einfach Aufgaben für die EDV eintragen und wir dabei automatisch über einen Verteiler per E-Mail benachrichtigt werden. Der Verteiler existiert bereits. Wie schaffe ich es die Öffentlichen Aufgaben anzulegen (muss ich das lokal auf meinem PC machen oder auf dem Exchange). Es soll ausserdem jeder darauf Zugriff haben und was erstellen und ändern können.

 

Grüße

[Cybquest 36]

Einen öffentlichen Ordner für Aufgaben erstellen dürfte kein Problem sein. Mit entspr. Berechtigungen kann man den auch vom Client aus anlegen.

Damit jedoch eine Mail verschickt wird, wenn jemand darin eine neue Aufgabe erstellt, müsste ein bisschen gescriptet werden.

[Stixx 10]

Danke für die Antwort. Das mit den Berechtigungen und dem Ordner habe ich jetzt schon geschafft lediglich die automatische Mail sollte funktionieren, da diese Funktion imens wichtig ist

[Cybquest 36]

D.h. man müsste für den Order ein neues Aufgaben-Formular entwerfen und im Code sowas in der Art reinpacken:

 

Dim ComposeMode

CONST strVerteiler = "EDV"

Function Item_Write()

if ComposeMode = "" then ComposeMode = "Compose"
if ComposeMode = "Compose" OR item.Owner <> item.ContactNames Then
	strUser = Application.GetNameSpace("MAPI").CurrentUser
	if item.BillingInformation = "" then item.BillingInformation = strUser
	Set myItem = Application.CreateItem(0)
	if ComposeMode = "Compose" then
		myItem.Subject = "Neuer Helpdesk-Auftrag <" & item.Subject & ">" 
		myItem.Body = "Erstellt von " & strUser & chr(13)
	else
		myItem.Subject = "Helpdesk-Auftrag <" & item.Subject & ">"
		myItem.Subject = myItem.Subject & " wurde neu zugeordnet"
		myItem.Body = "Verschoben von " & strUser & ": " & item.ContactNames & " --> " & item.Owner & chr(13)
	end if
	myItem.Body = myItem.Body & "FÄLLIG: " & item.DueDate & chr(13)
	myItem.Body = myItem.Body & "-->" & item.Subject
	On Error Resume Next
	strCc= item.ContactNames
	item.ContactNames = item.Owner
	strTo = item.Owner & "; " & strVerteiler
	myItem.To = strTo
	myItem.Cc = strCc
	myItem.Send
	If err Then
		MsgBox ("Fehler beim Senden an: " & strTo & ", Cc: " & strCc & chr(13) & "Ein Empfänger existiert vermutlich nicht!")
	Else
		MsgBox ("Auftrag gesendet an: " & strTo & ", Cc: " &strCc)
	End If

End if

End Function

Function Item_Read()

ComposeMode = "Read"

End Function

Function Item_Open()

if item.Subject = "" Then ComposeMode = "Compose" Else ComposeMode = "Read"
if ComposeMode = "Compose" then item.BillingInformation = Application.GetNameSpace("MAPI").CurrentUser

End Function

[Stixx 10]

Super vielen lieben Dank!!!