Spript User anlegen SharePoint 3.0

[Heinbloed 10]

Hallo zusammen,

 

ich bin auf der suche nach einen script mit dem ich User im Sharepoint anlegen kann. Wir setzen Sharepoint Services 3.0 ein. Ich muss mal eben für eine Testumgebung 160 User anlegen.

 

Gibt es da was fertiges ?

 

Vielen Dank

see you ...

[Heinbloed 10]

Hallo,

 

also das ganze mit einem Script zu machen habe ich aufgegeben. Mann kann die User aus der AD nehmen indem man sie einzeln doppelklickt. Da die User in der AD schön geordnet sind hat es nur 10min gedauert und meine 160 ausgesuchten User sind fertig :-)

 

Ich habe 1ne Stunde damit vertan nach einem Script zu suchen oder eines selber zu basteln:mad:

 

Manchmal denk einfach zu kompliziert :wink2:

 

allen ein schönes WE

see you ...

[thorgood 10]

Hallo,

 

klassisch ist der Weg auch eine Gruppe im AD anzulegen, ihr Benutzer zuzuordnen und in SharePoint diese Gruppe zu berechtigen.

 

thorgood

[itomix 10]

tach auch zusammen,

 

hiermal ein kleines Beispiel um mehere Benutzer testweis in einer OU anzulegen!

 

MfG

Tom Del Greco

 

'Anlegen von mehren Test Benutzer in einer Organisationseinheit der Domainestruktur
'Erstellt am 10.04.2007 von T.Del Greco 

'Developer Feedback: Keiner wird gekündigt für Scripte die man versteht ;o) ?

DIM RootDSE

Set RootDSE = GetObject("LDAP://RootDSE")
   Domainname=RootDSE.Get("DefaultNamingContext")

Set Domain  = GetObject("LDAP://" & Domainname)
   Nummber = inputBox("Wie viele Benutzer?")
   FavOU  = inputBox("In welcher OU sollen die User angelegt werden?")

Set wshNet = WScript.CreateObject("WScript.Network")

  Randomize

     random = Int(100 * rnd + 1)
     i = 00

  Do Until i > Nummber - 1

     strUsername        = "Test-User" & "-" & i
     strFirstName       = "Firstname"
     strLastName        = "Lastname"
     strHomeDir         = "\\" & wshNet.Computername & "\UserHomePath\" & strUsername
     strHomeDrive       = "Z"
     strBasisfile       = "\\" & wshNet.Computername
     strPasswd          = "!!HalloWelt2007"
     strLoginScript     = "\\" & wshNet.Computername & "\UserLoginScripte\login.vbs"       
     strTermProfilePath = "\\" & wshNet.Computername & "\TermUserPath\"
     strTermDir         = "\\" & wshNet.Computername & "\TerminalUser\"

Set objUser = Domain.Create("User", "CN=" & strUsername & ", OU=" & FavOU)

With objUser

     'Registger Map Generally

     .FirstName         	= strFirstName
     .LastName          	= strLastname
     .Displayname        	= strFirstName & " " & strLastname 
     .EmailAddress      	= strFirstname & "." & strLastname & "@itomix.org"
     .Description       	= "Test User" 
     .SetInfo
     '_ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _

     'Registger Map Account

     .sAMAccountName    	= strUsername	
     .UserPrincipalName 	= strUsername
     .SetPassword strPasswd
     .AccountDisabled   	= True
     .SetInfo
     '_ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _

     'Registger Map Profile

     .ProfilePath		= strHomeDir
     .HomeDrive		= strHomeDrive
     .HomeDirectory		= strBasisfile
     .ScriptPath		= strLoginScript
     .SetInfo
     '_ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ _

     'Register Map Terminal Service Profiles

     .AllowLogon = 1
     .TerminalServicesHomeDirectory = strTermDir      
     .TerminalServicesProfilePath = strTermProfilePath & strUsername
     .SetInfo   

End With

Set objUser = nothing
   i = i+1
   loop

Set Domain = nothing
   if i > 0 then
     'successfully 
   else
     'failed 
  end if