GPO + Scripting ... Windows Spiele von 8-12 verbieten...

[DerKlausi 10]

Hallo,

 

ich würde bei uns gerne zwischen 8 und 12 Uhr die Windows Spiele verbieten. (Wer die in der Zeit spielt ... naja... ich glaube nicht das sich da einer beschweren wird :))

 

wir nutzen ein 2k3 servernetzwerk mit xp clients.

 

ich dachte es mit batch dateien, geplanten tasks und gpos hinzubekommen.

 

mein erster schritt war ne batch anzulegen welche die startdateien umbenennt. startet man aber ein spiel, legt windows die datei einfach neu an...

 

soviel zum batch problem... ich weiss das ich über gpo das ausführen auch verbieten kann... könnte man bestimmt auch in ne batch einbauen. (damit wäre dann das ausführen der dateiversion untersagt...)

 

dann habe ich noch das problem, das ich (am besten über gpo) einen entsprechenden task im taskplaner einrichten muss, der um 8 uhr startet, und einen weiteren, der um 11:59 uhr ausgeführt wird. wie regle ich das über gpl? (auch über batchdatei?)

 

hat jemand sowas realisiert oder kann mir nützliche informationen geben?

[angoletti1 10]

Hi,

 

iich hatte das mal ganz frech folgendermaßen gelöst:

einfach die *.EXE der Spiele gesucht und diese bei jedem Anmelden mit der EXE des Windowstaschenrechner überschrieben. Dann konnten meine User mit Zahlen spielen :D Bis heute hat sich niemand getraut ein Problem mit den Spielen der IT zu melden :cool:

 

Grüße

Chris

[Volvotrucker 10]

LOL, gute Idee :D

[lefg 276]

Bist Du in einer dazu autorisierten Position?

[angoletti1 10]

Ja, war eigentlich total geil. Ich kannte mich so gut wie garnicht mit Scripting aus, daher ging das schön mit einer billigen 2-Zeilen-Batch und hat den Zweck voll und ganz erfüllt :p

[angoletti1 10]

Bist Du in einer dazu autorisierten Position?

? ? ?

[lefg 276]

Die Frage geht an den Threadowner. Sollte er ein Schergenadmin sein, Langeweile haben, in Nichtleitender Position sein, nicht autorisiert zu solchen Sachen, dann kann er leicht gewaltig auf die Plautze fallen.

 

Ansonsten die Richtlinie: Angegebene Windows-Anwendungen nicht ausführen, Benutzerkonfiguration, Administrative Vorlagen, System.

[DerKlausi 10]

Ich habe das zwar nicht zu entscheiden, aber umzusetzen und stehe an dem punkt wo ich eine lösung finden muss. Es ist gewünscht von der Leitung und ich soll sehen ob ich eine Umsetzung ohne Kosten machen kann.

 

das problem ist, es soll zwischen 12 und 14 uhr möglich sein. (Mittagspause)

 

einfaches überschreiben etc. verbietet es zwar, ist über ein startscript auch kein thema, aber das problem ist das es nicht generell unmöglich sein soll.

 

ich habe nun diverse tests gemacht... gpos per taskplan aktivieren etc. ... problem ist aber das die clients sich zu unterschiedlichen zeiten ein gp update holen ... und diesen zeitraum zu sehr heruntersetzen erzeugt ne menge traffic ... und ich habe noch keine möglichkeit gefunden gpos per taskplan zu deaktivieren. (zum aktivieren liegt auf gru**enrichtlinien.tä ja ein beispielscript)

[lefg 276]

....(zum aktivieren liegt auf gru**enrichtlinien.tä ja ein beispielscript)

Das habe ich noch nicht gesehen, kannst Du mir bitte mal einen Link/Tipp dahin geben?

 

Ein Gedanke: Die Spiele liegen nicht mehr lokal auf dem Rechner, sie legen auf dem Server; auf dem Clients liegen Links zum Gameshare des Servers. Die Berechtigung auf ein Share ist ziemlich einfach zu steuern.

 

Ich hatte da mal die Trialversion einer Registry Extension. Damit war es dann vom Server aus möglich, die Clients zu veranlassen, Änderenungen der GPO sofort abzuholen. Dafür gibt es aber auch einen Kommandozeilenbefehl, meine ich.

 

Das Ganze nützt aber nichts, falls es den Usern möglich ist, Spiele beliebigen Namens auf dem Stick mitzubringen. Da muss man dann wohl doch mit der Liste der erlaubten Anwendungen arbeiten.

[Bkolbe 10]

@ lefg:

 

ich denke er meint die Webseite Gruppenrichtlinien - Übersicht, FAQ und Tutorials, dort steht unter "Scripting" ein Beispiel wie man GPOs zeitgesteuert aktivieren kann.

 

@derklausi:

 

Probier doch mal folgendes: aktiviere die GPo mit dem SKript auf dem Server per geplante Tasks.

Auf den Clients bindest dort per geplante Tasks dann ein Gpupdate ein, das einmalig um 8:00 Uhr gestartet wird. Rechner die später hochfahren oder währenddessen neustarten holen sich eh die aktuellen GPOs.

Um 12:00 Uhr löscht du dann den Link der GPO auf die OU der Mitarbeiter und lässt wieder ein gpudate auf den Clients durchführen. Das Skript ist nicht komplizierter als das was du schon verwendet hast, ich habs aus dem Buch "Windows Scripting lernen" von Dr. Holger Schwichtenberg:

 

' GPMC_RemoveLinkGPO.vbs
' Entfernen einer Verknüpfung eines GPOs mit einem AD-Container
' Autor: Dr. Holger Schwichtenberg
' verwendet: GPMC Objects
' ===========================================================

Option Explicit

Dim gpm
Dim gpmDomain
Dim GPO
Dim Links, Link
Dim objContainer

' Zu untersuchende AD-Domain
Const DOMAIN = "IT-Objects.net"
Const CONTAINER = "OU=Softwareentwicklung,DC=IT-Objects,DC=net"
Const GPOGUID = "{152B91EC-72A3-4FD0-B988-046DCA578D17}"

WScript.Echo "Zugriff auf Domain: " & DOMAIN

' Zugriff auf das Wurzelobjekt
Set gpm = CreateObject("GPMgmt.GPM")

' Zugriff auf Domain
Set gpmDomain = gpm.GetDomain(DOMAIN,"", gpm.GetConstants().UseAnyDC)

' Zugriff auf den Container
Set objContainer = gpmDomain.GetSOM(CONTAINER)

WScript.Echo "Zugriff auf Container: " & CONTAINER

' Zugriff auf GPOLinks
Set Links = objContainer.GetGPOLinks()

WScript.echo "GPOs vor dem Löschen:"
' Schleife über alle Links in dem Container
For Each Link In Links
Set GPO = gpmDomain.GetGPO(Link.GPOID)
WScript.Echo "Name:" & GPO.DisplayName
Next

WScript.echo vbCrLf

' Suche des zu entfernenden GPOs
For Each Link In Links
Set GPO = gpmDomain.GetGPO(Link.GPOID)
If Link.GPOID = GPOGUID Then ' Link gefunden -> löschen!
	Link.Delete()
	WScript.Echo "GPO-Verknüpfung " & GPO.DisplayName & " wurde entfernt!"
	Exit For
End If
Next

WScript.echo vbCrLf

' Zugriff auf GPOLinks
Set Links = objContainer.GetGPOLinks()

WScript.echo "GPOs nach dem Löschen:"
' Schleife über alle Links in dem Container
For Each Link In Links
Set GPO = gpmDomain.GetGPO(Link.GPOID)
WScript.Echo "Name:" & GPO.DisplayName
Next

 

und nach der Mittagspause machst du das gleiche wie in der Früh, wenn du zum Feierabend die Spiele nicht wieder erlauben willst, dann kannst du dir das aktivieren der GPO morgens sparen.

 

Schreib bitte ob es funtkioniert, man weiß ja nie wozu man sowas mal brauchen könnte...