Win2kServer: jedes Konto eigenes Netzlaufwerk

[Sancezz 10]

Hiho,

ich habe 19 Windows NT 4.0 Schüler-Computer und einen Windows 2000 Server Lehrer-Computer.

 

Nun habe ich es mir so gedacht, dass ich für jeden Schüler ein Benutzerkonto in der Windows 2000 Server Domäne anlege. Jeder Schüler benötigt aber ein eigenes nur für ihn les- und schreibbares Netzlaufwerk, welches auf einen Ordner auf dem Server verweist.

 

Ich könnte die folgenden 4 Schritte von Hand erledigen:

- Benutzerkonto anlegen

- Benutzer-Ordner anlegen

- NTFS-Berechtigungen zu dem Ordner setzen, damit nur der Schüler drauf kommt

- Ordner freigeben

 

Ich möchte es den Lehrern aber erleichtern und es so konfigurieren, dass ich nur die Benutzerkonten anlegen muss und evtl. noch ein paar Einstellungen machen und der Server automatisch die letzten 3 Schritte übernimmt.

 

Könnt ihr mir sagen wie ich das mache?

 

 

Mit freundlichen Grüßen

Sancezz

[lefg 276]

Hallo und herzlich Willkommen am Board :),

 

das Thema Anlegen von Konten und Verzeichnissen per Skript wurde hier am Board schon behandelt, es gibt einen umfangreichen Thread dazu.

 

Wurde schon (die) Suche(n) bemüht?

 

Solltest Du nichts finden, dann helfe ich gerne weiter.

 

Gruß

 

Edgar

[Cybquest 36]

Wenn man im AD bei den Eigenschaften des Benutzers auf dem Reiter "Profil" unter Basisordner ein Laufwerk mit einem entspr. UNC-Pfad (z.B. \\server\user$\username) verbindet, wird dieser autom. mit den entspr. Rechten angelegt.

Was, glaub ich, nicht geht ist, dass eine Freigabe auf das Userlaufwerk angelegt wird! Daher hab ich user$ als übergeordnete Freigabe angegeben...

[marka 587]

In den Profileigenschaften musst Du angeben, als welches Laufwerk die Freigabe verbunden werden soll (z.B.: U: für "user") und folgenden String eingeben:

\\<servername>\<freigabename>\%USERNAME%

 

Beispiel:

\\Server01\user$\%USERNAME%

 

Die Systemvariable "%USERNAME%" wird beim Klick auf "Übernehmen" oder "OK" automatisch in den Benutzernamen umgewandelt.

[Sancezz 10]

Ok, ich habe hier im Board ein Skirpt gefunden, das automatisch die Konten anlegt, nur leider hat es keine Optionen für das Netzlaufwerk!

 

Kann mir das einer erweitern?

Ich suche schon den ganzen Tag danach, finde aber nix!

 

Das Skript:

' (C) 2005 by Markus Kafurke
' marka-it.net

msg = "Kurzbeschreibung:" & vbCr & "Dieses Skript legt automatisiert neue Konten an und liest die dafür nötigen Angaben aus C:\user.txt ." & vbCr & vbCr & "Skript jetzt ausführen?"
antwort = MsgBox(msg, vbYesNo + vbQuestion)
if antwort = vbNo then 
 MsgBox "Abbruch", vbExclamation
 WScript.Quit
end if
protokoll = "C:\protokoll.txt"

' Das WScript.Network-Objekt liefert den Namen des Computers,
' der als Vorgabe angeboten wird
'SYS: Windows Script Host Runtime Library
Set net = CreateObject("WScript.Network")

ComputerName = InputBox("Bitte geben Sie den Computernamen ein!",,net.ComputerName)
On Error Resume Next
Set computer = GetObject("WinNT://" & ComputerName & ",computer")
If Err.number = 0 Then
  MsgBox "Verbindung hergestellt."
Else
  MsgBox "Keine Verbindung zu " & ComputerName
  WScript.Quit
End If
On Error Goto 0

dateiname = InputBox("Wo liegen die Kontoinformationen?",,"C:\user.txt")

' Datei öffnen
'SYS: Microsoft (r) Script Runtime
Set fs = CreateObject("Scripting.FileSystemObject")
If Not fs.FileExists(dateiname) Then
  MsgBox "Die Datei existiert am angegebenen Ort nicht!"
  WScript.Quit
End If

Set infos = fs.OpenTextFile(dateiname)

' Protokolldatei öffnen
Set output = fs.CreateTextFile(protokoll, True)

' Datei zeilenweise bis zum Ende (atEndOfStream) lesen:
Do Until infos.AtEndOfStream
  ' eine Zeile einlesen
  zeile = infos.ReadLine

  ' Informationen durch Semikola splitten
  details = Split(zeile, ";")

  ' Konto anlegen
  Set kontoneu = computer.Create("User", Trim(details(0)))
  kontoneu.SetPassword Trim(details(1))
  kontoneu.Description = Trim(details(2))
  On Error Resume Next
  kontoneu.SetInfo
  If Err.number = 0 Then
     WriteLog details(0) & " angelegt."
     AddToGroup Trim(details(3)), kontoneu.ADsPath
  Else
     WriteLog details(0) & " konnte nicht angelegt werden!"
  End If
  Err.Clear
  On Error Goto 0
Loop

' Dateien schließen
infos.Close
output.Close

' Protokoll anzeigen:
'SYS: Microsoft (r) Script Runtime
Set wshshell = CreateObject("WScript.Shell")
wshshell.Run """" & protokoll & """"


Sub AddToGroup(gruppenname, kontoname)
  On Error Resume Next
  Set gruppe = GetObject("WinNT://" & ComputerName & "/" & gruppenname & ",group")
  gruppe.Add kontoname
  gruppe.SetInfo
  If Err.number = 0 Then
     WriteLog "Konto ist Mitglied in Gruppe " & gruppenname
  Else
     WriteLog "Konto konnte nicht zum Mitglied in Gruppe " & gruppenname & " gemacht werden."
  End If
  Err.Clear
End Sub

Sub WriteLog(text)
  ' eine Zeile ins Protokoll schreiben
  output.WriteLine text
End Sub

 

MfG

Sancezz