Hintergrundbild bei Serverseitggespeicherten Profilen

[yogi_20o0 10]

Wir haben einen SAMBA PDC und diverse Windows 2000 und XP Clients. Nun ist es so, das die User ein Hintergrundbild (eine Telefonliste) haben die lokal auch wunderbar funktioniert. Das Bild liegt auf einem Netzlaufwerk und wird immer schön geladen.

 

Das Netzlaufwerk ist durch das Anmeldescript immer vorhanden, Offlinedateien sind deaktiviert.

 

Wenn der User jetzt seinen Arbeitsplatz wechselt, dann ist zwar in den Desktopeinstellungen das Bild noch angewählt, wird nach der Anmeldung jedoch nicht angezeigt!

 

Erst wenn ich die Desktopeinstellungen (durch Klicken auf den schon vorhandenen Eintrag des Bildes) mittels OK Schaltfläche verlasse, dann wird mir auch das Bild wieder angezeigt.

 

Wieso?

Wo kann ich das abstellen?

 

Kurzform:

Lokal klappt das mit dem Hintergrundbild. Beim Wechsel des Arbeitsplatzes jedoch nicht. Die restlichen Einstellungen der serverseitig gespeicherten Profile sind ok, da auch die Dateien auf dem Desktop usw. mit übertragen werden.

[Q -kju:- 10]

Desktop Hintergrund wird nicht gespeichert - administrator

 

Windows erstellt leider vom gewählten Wallpaper immer seine eigene Datei (meist Wallpaper1.bmp) im Ordner "%USERPROFILE%\Lokale Einstellungen\Anwendungsdaten\Microsoft". Da dieser Ordner nicht propagiert wird, bleibt das Wallpaper auf dem Rechner, auf welchem es eingerichtet wurde.

Die Lösung des Problems liegt im Skripten eines Abmeldeskripts, das "HKCU\Control Panel\Desktop\Wallpaper" ausliest, das Wallpaper ins %APPDATA%\Microsoft Verzeichnis kopiert und anschließend den Registrierungseintrag updated. Das Skript kann mittels GP eingerichtet werden. (Benutzerkonfiguration\Windows-Einstellungen\Skripts\Abmelden)

 

SalvageWallpaper.wsf [spitzklammern bei Tags (1, 2, vorletzte und letzte Zeile) bitte hinzufügen, sind im Posting nicht erlaubt]

-------------------------------------

job

script language="VBScript"

 

'Deklariere die Variablen

Dim wshShell, sAppData, sWallpaper, fso

 

'Erstelle das Shell-Objekt

Set wshShell = WScript.CreateObject( "WScript.Shell" )

 

'Ermittle den Pfad der Anwendungsdaten

sAppData = wshShell.ExpandEnvironmentStrings( "%APPDATA%" )

 

'Beende falls Pfad nicht gefunden

If IsNull( sAppData ) Or Len( sAppData ) = 0 Then

WScript.Quit

End If

 

'Ergänze den Pfad mit Unterordner Microsoft und Dateiname Wallpaper.bmp

sAppData = sAppData & "\Microsoft\Wallpaper.bmp"

 

'Ermittle das aktuelle Wallpaper

sWallpaper = wshShell.RegRead( "HKCU\Control Panel\Desktop\Wallpaper" )

 

'Beende falls kein Wallpaper gewählt wurde oder es sich bereits um ein salvaged Wallpaper handelt

If IsNull( sWallpaper ) Or Len( sWallpaper ) = 0 Or sWallpaper = "(Kein)" Or sWallpaper = sAppData Then

WScript.Quit

End If

 

'Erstelle das Dateisystem-Objekt

Set fso = WScript.CreateObject( "Scripting.FileSystemObject" )

 

'Kopiere das Wallpaper in das Anwendungsdaten-Verzeichnis

fso.CopyFile sWallpaper, sAppData

 

'Aktualisiere den Registrierungseintrag

wshShell.RegWrite "HKCU\Control Panel\Desktop\Wallpaper", sAppData

 

/script

/job

[yogi_20o0 10]

Das Script ist gut.

Ich werde es ausprobieren, falls ich die Daten der "Lokale Einstellungen" nicht in die serverseitig gespeicherten Profile integriert bekomme, die im Übrigen in der Exclusion List der ntuser.ini oder im Reghistry Key HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Winlogon unter "ExcludeProfileDirs"="Lokale Einstellungen;Temporary Internet Files;Verlauf;Temp" zu finden sind.

 

Danke