VBS - Verteilerlisten anlegen

[phoenixcp 10]

Hallo Freunde der Gesangsmusik :D

 

Ich hatte heute seit langer Zeit mal wieder eine Begegnung der dritten Art und musste für die Vorbereitung eines Repro-Szenarios eine größere Anzahl von Verteilerlisten anlegen. Das habe ich pauschal per ADSI-Script gemacht, wobei ich nach längerer Abstinenz recht flott wieder an meine Grenzen gestossen bin. Aber ich hab es hinbekommen. Falls mal jemand sowas braucht, dachte ich mir, will ich euch den entsprechenden Code nicht vorenthalten:

ADS_GROUP_TYPE_GLOBAL_GROUP = &h2
ADS_GROUP_TYPE_LOCAL_GROUP = &h4
ADS_GROUP_TYPE_UNIVERSAL_GROUP = &h8
ADS_GROUP_TYPE_SECURITY_ENABLED = &h80000000

strContainer = "OU=TESTOU"
strName = "zz_DistListTest_"

'***********************************************
'*         Connect to a container              *
'***********************************************
Set objRootDSE = GetObject("LDAP://rootDSE")
If strContainer = "" Then
  Set objContainer = GetObject("LDAP://" & _
    objRootDSE.Get("defaultNamingContext"))
Else
  Set objContainer = GetObject("LDAP://" & strContainer & "," & _
    objRootDSE.Get("defaultNamingContext"))
End If
'***********************************************
'*       End connect to a container            *
'***********************************************
for i = 1 to 500
	Set objGroup = objContainer.Create("group", "cn=" & strName & i)
	objGroup.Put "sAMAccountName", strName & i
	objGroup.Put "Mail", strName & i & "@tld.de"
	objGroup.Put "groupType", ADS_GROUP_TYPE_UNIVERSAL_GROUP
	objGroup.Put "Info", "automatically created DistributionList"
	objGroup.SetInfo
	objGroup.MailEnable
	objGroup.SetInfo
	objGroup.Put "DisplayName", "#zz_" & strName & i
	objGroup.Put "MailNickname", "Alias#_" & strName & i
	objgroup.Put "ReportToOriginator", FALSE
	objGroup.Put "ReportToOwner", FALSE
	objGroup.Put "HideDLMembership", FALSE
	objGroup.Put "msExchHideFromAddressLists", FALSE
	objGroup.SetInfo
Next

MsgBox "DONE"
[/Code]

 

Dieser Code legt 500 Verteilerlisten vom Typ Universal-Distribution in einer OU "TestOU" an, mailenabled diese und befüllt anschließend noch exchangerelevante Werte.

 

Wiederverwendung und Modifikation des Codes sind ausdrücklich erlaubt.

 

Viel Spaß damit

 

Carsten