Export Eventlog

[LutzBesser 10]

Hallo,

 

ich habe folgendes Script in der Technet für den Export von Eventlogs für 2003 Server gefunden. Nun hätte ich gerne ein paar Änderungen, die mich Stunden kosten würden.

Hier ist das Script.

 

strComputer = "." 
Set objWMIService = GetObject("winmgmts:" _ 
   & "{impersonationLevel=impersonate,(Backup)}!\\" & _ 
       strComputer & "\root\cimv2") 

Set colLogFiles = objWMIService.ExecQuery _ 
   ("Select * from Win32_NTEventLogFile where LogFileName='Application'") 

For Each objLogfile in colLogFiles 
   errBackupLog = objLogFile.BackupEventLog("c:\scripts\application.evt") 
   If errBackupLog <> 0 Then         
       Wscript.Echo "The Application event log could not be backed up." 
   Else 
       objLogFile.ClearEventLog() 
   End If 
Next 

 

Geändert hätte ich gerne den Ausgabename des Eventligs. Wie muss ich das Script umbauen, damit vor dem Nqmen das aktuelle Datum steht? Also 20110530_application.evt.

Des Weiteren steht in der Schleife, dass im Fehlerfall ein Fenster aufgeht. Wie kann ich das Script umschreiben, dass im Fehlerfall ein Eintrag in eine Txt-Datei gemacht wird?

 

Danke für Tipps.

[Mokkujin 10]

So gehts ....

strComputer = "." 
Dim FIL_LOG		:	FIL_LOG = "C:\" & Replace(WScript.ScriptName,".vbs","") & ".log"  '-- Logfile
Dim ObjFso		:	Set ObjFso = CreateObject("Scripting.FileSystemObject")

Set objWMIService = GetObject("winmgmts:" _ 
   & "{impersonationLevel=impersonate,(Backup)}!\\" & _ 
       strComputer & "\root\cimv2") 

Set colLogFiles = objWMIService.ExecQuery _ 
   ("Select * from Win32_NTEventLogFile where LogFileName='Application'") 

For Each objLogfile in colLogFiles 
   errBackupLog = objLogFile.BackupEventLog("c:\scripts\" & GetDate() & "_application.evt") 
   If errBackupLog <> 0 Then         
       WriteLog strComputer & " -- The Application event log could not be backed up." 
   Else 
       objLogFile.ClearEventLog() 
   End If 
Next

Function GetDate()
'------------------ Ermittelt das aktuelle Datum
Dim Monat 	: Monat = Month(now)
Dim Tag 	: Tag = Day(Now)
Dim Jahr 	: Jahr = Year(now)

If Monat < 10 then 
Monat = "0" & Monat 
End If
If Tag < 10 Then
Tag = "0" & Tag
End If
GetDate = Jahr & Monat & Tag
End Function

Function WriteLog(Inhalt)
'------------------ Schreibt ein Logfile
Dim FileOut
Set FileOut = ObjFso.OpenTextFile(FIL_LOG,8,true)
FileOut.WriteLine (Inhalt)
FileOut.Close
Set FileOut = Nothing
End Function

bearbeitet 8. Juni 2011 von Mokkujin

[LutzBesser 10]

Danke, ich werde es testen.