Alle E-Mail Adressen anzeigen

Herbert Leitner · 20. Juni 2006

Hallo!

Wie schaffe ich es am Exchange Server 2003, alle konfigurierten SMTP - Adressen auszulsen.

Ich habe verscheidene Benutzer und verschiedene Funktionen und damit einen "Haufen" E-Mail Adressen. Zum Teil pro Benutzer also mehrere Adressen.

Ohne jetzt bei allen Benutzern nachsehen zu müssen, gibt es die Möglichkeit, alle Adressen anzuzeigen?

LDAP, WMI oder VBS können das sicher, das ist mit aber zu komplex (ich schaff das nicht!) ;-)

tks!

Herbert

GuentherH · 20. Juni 2006

HI.

Boardsuche oder hier - http://www.sbspraxis.de/exchange/ex03020/ex03020.html

LG Günther

WSUSPraxis · 20. Juni 2006

'''''''''''''''''''''''''''''''''''''''''''''''''''''

' AD-Mailadressen_anzeigen.vbs

' Beschreibung

'

' Version: 1.1a

' Datum: 21.04.2005/23.08.2005

' Autor: Nils Kaczenski (Vorname at Nachname .de)

' Letzte Änderungen:

'

' Nils Kaczenski stellt dieses Skript ohne jede

' Gewährleistung zur Verfügung.

' Die Verwendung geschieht auf eigene Gefahr.

'

'''''''''''''''''''''''''''''''''''''''''''''''''''''

Option Explicit

Dim strMail '

Dim arrMember '

Dim arrObjectClass '

Dim arrProxyAddresses '

Dim i '

Dim objConn '

Dim objExplorer '

Dim objRSAD '

Dim objRSlokal '

Dim strAusgabe '

Dim strConn '

Dim strMember '

Dim strObjectClass '

Dim strSQL '

Dim objRoot

Dim strDomain

Set objConn = CreateObject("ADODB.Connection")

Set objRSlokal = CreateObject("ADODB.Recordset")

' Domänenzugriff ...

set objRoot = GetObject("LDAP://rootDSE")

strDomain = objRoot.Get("DefaultNamingContext")

' Datenbankzugriff ...

strConn = "Provider=ADsDSOObject;"

objConn.Open strConn

' Zugriff auf die gesamte Tabelle

strSQL = "SELECT name,mailNickname,mail,proxyAddresses,member,objectClass " _

& "FROM 'LDAP://" & strDomain & "' WHERE mailNickname='*'"

Set objRSAD = objConn.Execute(strSQL)

' lokales Recordset zur Anzeige definieren

objRSlokal.Fields.Append "Mailadresse", 202, 255

objRSlokal.Fields.Append "Name", 202, 255

objRSlokal.Fields.Append "Alias", 202, 255

objRSlokal.Fields.Append "Typ", 202, 255

objRSlokal.Fields.Append "Mitglieder", 202, 16384

objRSlokal.Open

Do Until objRSAD.EOF

arrProxyAddresses = objRSAD("proxyAddresses")

strMail = objRSAD("mail")

If Not IsNull(objRSAD("member")) Then

arrMember = objRSAD("member")

strMember = Join(arrMember, "<br>")

Else

strMember = ""

End If

arrObjectClass = objRSAD("objectClass")

strObjectClass = arrObjectClass(UBound(arrObjectClass))

For i=0 To UBound(arrProxyAddresses)

If LCase(Left(arrProxyAddresses(i),5)) = "smtp:" Then

' Neuen Datensatz lokal einfügen

objRSlokal.AddNew

objRSlokal("Name") = objRSAD("name")

objRSlokal("Alias") = objRSAD("mailNickname")

objRSlokal("Typ") = strObjectClass

objRSlokal("Mailadresse") = Mid(arrProxyAddresses(i),6)

objRSlokal("Mitglieder") = strMember

objRSlokal.Update

End If

Loop

objRSlokal.Sort="Mailadresse"

objRSlokal.MoveFirst

strAusgabe = objRSlokal.GetString(2, -1, "</TD><TD>", "</TD></TR>" _

& vbCrLf & "<TR><TD>", " ")

strAusgabe = "<HTML><BODY style=""font-family:sans-serif;"">" _

& "<TABLE border=""1""><TR><TD>" _

& strAusgabe & "</TD></TR></TABLE></BODY></HTML>"

Set objExplorer = CreateObject("InternetExplorer.Application")

objExplorer.Navigate "about:blank"

objExplorer.ToolBar = 0

objExplorer.StatusBar = 0

objExplorer.Width=500

objExplorer.Height = 400

objExplorer.Left = 0

objExplorer.Top = 0

objExplorer.Visible = 1

objExplorer.document.writeln(strAusgabe)

carlito · 20. Juni 2006

@ Der Schwabe

Dieses Script ist auf Günters Seite verlinkt. Copy & Paste wäre also nicht nötig gewesen :P

Anmelden

Alle E-Mail Adressen anzeigen

Empfohlene Beiträge

Herbert Leitner 10

GuentherH 61

WSUSPraxis 48

carlito 10

Erstelle ein Benutzerkonto oder melde dich an, um zu kommentieren

Benutzerkonto erstellen

Anmelden

Menu

Aktivitäten