wie finde ich raus wann ein PC das letzte Mal am Netzwerk war

[Sage24 10]

Der Titel sagt schon alles aus;-)

 

Kann ich das über die DNS-Leasetimes rausfinden oder direct über ADs?

 

Gruß

Adrian

[Operator 10]

Hi,

 

wie ein Benutzer meldet sich auch ein Computer in der Domäne an.

Für diesen Zweck habe ich mal ein Script gebastelt, um den letzten Anmeldezeitpunkt eines Rechners rauszufinden. Das Script ist so konzipiert, daß ich einen Computernamen eingebe und mit Datum/Uhrzeit der letzten Anmeldung präsentiert wird.

Eine Liste spuckt das Teil aber nicht aus.

 

Im Script selbst muss nur noch der NetBIOS Domain Name eingetragen werden.

 

Einfach als GetLastLogonDateTime.vbs abspeichern und Doppelklicken:

Dim Time, objNetwork, objTrans, strNetBIOSDomain, strComputer
Dim objOU, objUser, objRootDSE, objLastLogon
Dim strContainer, strDNSDomain
Dim intLastLogonTime, intGuyTime

strComputer = InputBox("Computername? :") & "$"

Const ADS_NAME_INITTYPE_GC = 3
Const ADS_NAME_TYPE_NT4 = 3
Const ADS_NAME_TYPE_1779 = 1

strNetBIOSDomain = "[b]DOMAIN[/b]"

Set objNetwork = CreateObject("Wscript.Network")
Set objTrans = CreateObject("NameTranslate")
objTrans.Init ADS_NAME_INITTYPE_GC, ""
objTrans.Set ADS_NAME_TYPE_NT4, strNetBIOSDomain & "\" & strComputer
strComputerDN = objTrans.Get(ADS_NAME_TYPE_1779)

Set objRootDSE = GetObject("LDAP://RootDSE") 
strDNSDomain = objRootDSE.Get("DefaultNamingContext")

Set obj =GetObject("LDAP://" & strComputerDN )
Set objLastLogon = obj.Get("lastLogon")
intLastLogonTime = objLastLogon.HighPart * (2^32) + objLastLogon.LowPart 
intLastLogonTime = intLastLogonTime / (60 * 10000000)
intLastLogonTime = intLastLogonTime / 1440

Wscript.Echo "Letzte Computeranmeldung: " & intLastLogonTime + #1/1/1601# 

 

Gruß

Andre